Rsi Dynamic level

[wahabdeen]

this is amibroker afl please convert metastock


//Dynamic Levels RSI version V.1.0
// Afl by Karthikmarar
// www.karthikmarar.blogspot.com
//============================================================
_SECTION_BEGIN("RSI with Dynamic Levels");
SetChartBkColor(colorWhite);
DZbuy = Param("Buy Zone Probability",0.1,0.1,0.5,0.1);
DZsell = Param("Sell Zone Probability",0.1,0.1,0.5,0.1);
Period = Param("Period", 14, 2, 30, 1);
Lb = Param("LookBack Period",60,40,120,1);
mySig = RSI(Period);
jh = HHV(mySig,Lb);
jl = LLV(mySig,Lb);
jc = (WMA((jh-jl),Period)*0.50)+WMA(jl,Period);
Hiline = jh-jc*DZbuy;
Loline = jl+jc*DZsell;
midline = (jh-jl)/2;
Plot(HiLine,"",colorDarkRed,1|styleThick| styleDashed);
Plot(LoLine,"",colorDarkRed,1| styleDashed|styleThick);
Plot(jc,"",colorBlack,1| styleDashed|styleThick);
R = ( 4 * mySig + 3 * Ref(mysig,-1) + 2 * Ref(mysig,-2) + Ref(mysig,-3) ) / 10;;
Plot(R,"",IIf(R>jc,colorLime,colorRed),1|styleThick);
kh = IIf(R>Hiline, R,Hiline);
PlotOHLC( kh,kh,Hiline,Hiline, "", IIf(R>HiLine,colorLime,colorBlack), styleCloud );
kl = IIf(R <Loline, R,Loline);
PlotOHLC( Loline,Loline,kl,kl, "", IIf(R<HiLine,colorRed,colorBlack), styleCloud );
Title = " " +Name() +
" Floating level RSI V.1.0 - " +
WriteVal(period, format=1.0) + " ";

 

[HappyLife]

DZbuy:=Input("Buy Zone Probability",0.1,0.5,0.1);
DZsell:=Input("Sell Zone Probability",0.1,0.5,0.1);
Period:=Input("Period",2, 30, 14);
Lb:=Input("LookBack Period",40,120,60);

mySig:= RSI(Period);
jh:=HHV(mySig,Lb);
jl:=LLV(mySig,Lb);
jc:=(Mov((jh-jl),Period,W)*0.50)+Mov(jl,Period,W);
Hiline:=jh-jc*DZbuy;
Loline:=jl+jc*DZsell;
midline:=(jh-jl)/2;
R:=( 4 * mySig + 3 * Ref(mysig,-1) + 2 * Ref(mysig,-2) + Ref(mysig,-3) ) / 10;
kh:=If(R>Hiline, R,Hiline);
kl:=If(R <Loline, R,Loline);

Hiline;
kh;
R;
kl;
Loline;

 

[wahabdeen]

Thanks HappyLife