Candlestick Plugin

Hi all,

Is there any Plug in for Exploration of Candlesticks. Say for example i want to scan all the Stocks with bearish Engulfin??? How to do it???


Thanks

Open explorer from tools ---> name it bearish engulfing

In coloumn A type:
O > C And
Ref(O,-1) < Ref(C,-1) And
C < Ref(O,-1) And
O > Ref(C,-1) And
H > Ref(H,-1) And
L < Ref(L,-1)

Now go to filter and type ColA
The explorer is ready

Oxy

Thankx Oxy,
but i dont just want it for Bearish Engulfing i want it for Several other patterns like Morning Star, Doji Star, Evening Star, Tweezers etc.


Can u name a plug in for it??


Thanks

There's a plugin called Nison's candlesticks unleashed but that has only 3 explorations and the entire plugin is a lot of bullcrap. The best way to add the exploration you want is to code it yourself (which can be a hectic process). I can help you if you want...

go to the explorer and click on new

click in Col A
this will enable the Functions.. button at the bottom

click of Functions.., this will open up a new box.

choose Candlestick on from list in the left hand side. this will bring all the candlestick functions on the right side. choose the one u want.

pls refer to the formula premier. all the details are given there.

cheers,
jdm.

hi,,swagat..
oxy is right ,,,u have to feed in ,, seperate explorers,,,for candles which will much better..even i did this for reversal signals,,adn ,i got,,
but i got signals everyday ,,as per the aspect,,that is the draw back

Hey JDM,
wow, that makes the job a million times easier
I forgot candlestick functions were already coded into metastock
thanks

Thanks Oxy Joyda, And Renu for ur replies. Will check after markets.



Thanks a lot

Some Candlestick formula are as under :;

Candle - 3 Black Crows
If(Ref((OPEN-C),-2)>Mov(Abs(OPEN-C),10,S), {long black}
If(Ref((OPEN-C),-1)>Mov(Abs(OPEN-C),10,S), {long black}
If((OPEN-C)>Mov(Abs(OPEN-C),10,S), {long black}
If(Ref((Abs(OPEN+C)/2),-1)<Ref((Abs(OPEN+C)/2),-2), {lower midpoint}
If((Abs(OPEN+C)/2)<Ref((Abs(OPEN+C)/2),-1), {lower midpoint}
-1,0),0),0),0),0)

Candle - 3 White Soldiers
If(Ref((C-OPEN),-2)>Mov(Abs(OPEN-C),10,S), {long white}
If(Ref((C-OPEN),-1)>Mov(Abs(OPEN-C),10,S), {long white}
If((C-OPEN)>Mov(Abs(OPEN-C),10,S), {long white}
If(Ref((Abs(OPEN+C)/2),-1)>Ref((Abs(OPEN+C)/2),-2), {higher midpoint}
If((Abs(OPEN+C)/2)>Ref((Abs(OPEN+C)/2),-1), {higher midpoint}
1,0),0),0),0),0)

Candle - 3 Crows & Soldiers
If((Fml("Candle - 3 Black Crows")),-1,If((Fml("Candle - 3 White Soldiers")),1,0))

Candle - Dark Cloud Cover
If(Ref(C-OPEN,-1)>(Mov(Abs(OPEN-C),10,S)), {long white}
If(C<Ref(C,-1),If(C>Ref(OPEN,-1), {close within previous body}
If(Ref(Abs((OPEN+C)/2),-1)>Ref(Mov(C,10,E),-1), {uptrend}
If(OPEN>Ref(H,-1), {open at new high}
-1,0),0),0),0),0)

Candle - Engulfing - Bullish
If(Ref(OPEN,-1)>Ref(C,-1),
If(C-OPEN>(Mov(Abs(OPEN-C),10,S)),
If(C>Ref(OPEN,-1),
If(Ref(Abs((OPEN+C)/2),-1)<Ref(Mov(C,10,E),-1),
If(OPEN<Ref(C,-1),1,0),0),0),0),0)

Candle - Evening Star

If(Ref(C-OPEN,-2)>(Mov(Abs(OPEN-C),10,S)),
If(Ref(Abs(C-OPEN),-1)<(Mov(Abs(OPEN-C),10,S))/2,
If(Ref(C,-1)>Ref(C,-2),
If(Ref(OPEN,-1)>Ref(OPEN,-2),
If(C<Ref((OPEN+C)/2,-2),-1,0),0),0),0),0)

Candle - Hammer

If(Abs((H+L)/2)<Ref(Mov(C,10,E),-1), {down trend}
If(Min(OPEN,C)>H-((H-L)/3), {body in upper 1/3}
If(C<Ref(C,-1),If(OPEN<Ref(OPEN,-1), {body gap}
1,0),0),0),0)

Candle - Hanging Man

If(Abs((H+L)/2)>Ref(Mov(C,10,E),-1), {up trend}
If(Min(OPEN,C)>H-((H-L)/3), {body in upper 1/3}
If(C>Ref(C,-1),If(OPEN>Ref(OPEN,-1), {body gap}
-1,0),0),0),0)

Candle - Harami - Bearish

If(C<(OPEN), {black day}
If(Ref(C-OPEN,-1)>Mov(Abs(OPEN-C),10,S), {long white}
If(C>Ref(OPEN,-1),If(OPEN<Ref(C,-1), {engulfment}
If(Ref(Abs((H+L)/2),-1)>Ref(Mov(C,10,E),-1), {up trend}
-1,0),0),0),0),0)

Candle - Harami - Bullish

If(C>OPEN, {white day}
If(Ref(OPEN-C,-1)>Mov(Abs(OPEN-C),10,S), {long black}
If(C<Ref(OPEN,-1),If(OPEN>Ref(C,-1), {engulfment}
If(Ref(Abs((H+L)/2),-1)<Ref(Mov(C,10,E),-1), {down trend}
1,0),0),0),0),0)

Candle - Morning Star

If(Ref(OPEN-C,-2)>(Mov(Abs(OPEN-C),10,S)),
If(Ref(Abs(C-OPEN),-1)<(Mov(Abs(OPEN-C),10,S))/2,
If(Ref(C,-1)<Ref(C,-2),
If(Ref(OPEN,-1)<Ref(OPEN,-2),
If(C>Ref((OPEN+C)/2,-2),1,0),0),0),0),0)

Candle - Piercing Line

If(C-OPEN>(Mov(Abs(OPEN-C),10,S)), {long white}
If(Ref(OPEN-C,-1)>(Mov(Abs(OPEN-C),10,S)), {long black}
If(C>Ref(C,-1),If(C<Ref(OPEN,-1), {close inside previous body}
If(Ref(Abs((OPEN+C)/2),-1)<Ref(Mov(C,10,E),-1), {down trend}
If(OPEN<Ref(L,-1),1,0),0),0),0),0),0)

All formulas taken from http://trader.online.pl/MSZ/e-0-tytulowa-c.html

Thanks a lot moneypick.