Trading Price Rejections, Fakeouts

///////////////////////////////////////////////////

// Author : Bandlab
// Designed by : trader.trends

// Entry Setup: Wait for the 2 Day High/Low to be broken. if it happens at the opening with a gap, wonderful. Once the 2D H/L is broken, next is to wait for the Previous Close to be broken. When the Previous Close is broken the trade is on. if the PC is broken after the 2D High is broken, we Short the break of the PC, if the PC is broken after the 2D Low is broken, we go long. 

// Stops: for shorts, the 2D High, for Longs the 2D Low.

// Exits: So far I have looked at only closing at LTP. May refine the exits later.

// Reference : http://www.traderji.com/day-trading/37029-trading-price-rejections-fakeouts.html

//////////////////////////////////////////////////



RiskAmount=Param("Risk Amount",500,50,10000,50);
Profitfactor=Param("TP/SL Ratio ",1,0.1,100,0.1);
RiskPercentMin=Param("Risk Percent Min",30,50,250,50);
RiskPercentMax=Param("Risk Percent Max",76,50,250,50);



PlotOHLC(Open,High,Low,Close,"",colorWhite,styleCandle);


Sell=   H > Ref(HHV(H,2),-1) AND C<Ref(C,-1); 
Buy=   L < Ref(LLV(L,2),-1) AND C>Ref(C,-1); 


BuyPrice = IIf(Buy, Ref(C,-1),0);
SellPrice = IIf(Sell, Ref(C,-1),0);

BuySL =  IIf(Ref(L,-1)==Ref(C,-1), L, Ref(LLV(L,2),-1));
BuyTP = BuyPrice + (BuyPrice - BuySL )*Profitfactor;
SellSL = IIf(Ref(H,-1) == Ref(C,-1), H, Ref(HHV(H,2),-1));
SellTP = SellPrice - (SellSL - SellPrice )*Profitfactor;

riskPercent = IIf(Buy, (BuyPrice - BuySL)*10000/BuyPrice , IIf(Sell, (SellSL-SellPrice )*10000/SellPrice ,0));
Buy=IIf(Buy AND riskPercent > RiskPercentMin AND riskPercent < RiskPercentMax, 1, 0);
Sell=IIf(Sell AND riskPercent > RiskPercentMin AND riskPercent < RiskPercentMax, 1, 0);


shape=Buy*shapeUpArrow+Sell*shapeDownArrow;
PlotShapes(shape,IIf(Buy,colorGreen,colorRed),0,IIf(Buy,L,H)); 


//money management
lotSizeb = round((riskAmount/(BuyPrice-BuySL)));
lotSizes = round((riskAmount/(SellSL -SellPrice )));


Buystatus = IIf(Buy AND H>BuyTP , 1, 0);
Sellstatus = IIf(Sell AND L<sellTP , 1, 0);


if( Status("action") == actionIndicator ) 
(

Title = StrFormat("{{NAME}} - {{INTERVAL}} {{DATE}}  Op %g, , Hi %g, Lo %g, Cl %g (%.1f%%) {{VALUES}}",  O,H, L,C, SelectedValue( ROC( C, 1 ) ) )+"\n"+EncodeColor(colorWhite)+ "2DLH Breakout System" + " - " +  Name() +  EncodeColor(colorWhite) +

 "\n" +EncodeColor(colorYellow) + WriteIf(((BuyPrice) ) , "Position Size :  "+( lotSizeb )+"  ","")+ WriteIf(((SellPrice ) ) , "Position Size :  "+( lotSizes )+"  ","")+
WriteIf((BuyPrice), "GO LONG :  "+( BuyPrice)+"  ","")+
WriteIf( BuyTP , "     -     LONG TP :  "+(BuyTP )+" ","")+
WriteIf(BuySL , "    -    LONG SL :  "+(BuySL ),"")+

"\n"+
EncodeColor(colorRed) +
WriteIf(SellPrice , "GO Short :  "+( SellPrice )+"  ","")+
WriteIf(SellTP , "    -    Short TP :  "+(SellTP ),"")+
WriteIf( SellSL , "     -     Short SL :  "+(SellSL )+" ",""));




//exploration
AddColumn( IIf(Buy, 66, IIf(Sell, 83,01 )), "GO", formatChar, colorWhite, bkcolor= IIf(Sell,colorDarkRed,colorDarkGreen) );
AddColumn( IIf(Buy , BuyPrice, IIf(Sell , SellPrice,01 )), "ENTRY@", 1.2, colorWhite, bkcolor= IIf(Sell,colorDarkRed,colorDarkGreen) );
AddColumn( IIf(Buy , BuyTP , IIf(Sell , SellTP ,01 )), "TP@", 1.2, colorWhite, bkcolor= IIf(Sell,colorDarkRed,colorDarkGreen) );
AddColumn( IIf(Buy , BuySL , IIf(Sell , SellSL ,01 )), "SL@", 1.2, colorWhite, bkcolor= IIf(Sell,colorDarkRed,colorDarkGreen) );
AddColumn( IIf(Buy , Buystatus , IIf(Sell , Sellstatus ,01 )), "Status@", 1.2, colorWhite, bkcolor= IIf(Sell,colorDarkRed,colorDarkGreen) );
AddColumn( IIf(Buy , Lotsizeb, IIf(Sell, Lotsizes,01 )), "QTY", 1.0, colorWhite, bkcolor= IIf(Sell,colorDarkRed,colorDarkGreen) );
AddColumn( IIf(Buy , riskPercent , IIf(Sell, riskPercent ,01 )), "Risk%", 1.0, colorWhite, bkcolor= IIf(Sell,colorDarkRed,colorDarkGreen) );



// csv file

if (IsEmpty(StaticVarGet("EntrySignal"+Name())))
{
	StaticVarSet("EntrySignal"+Name(), 1);
}




   if ((StaticVarGet("EntrySignal"+Name()) == 1) && LastValue( Buy )  )  {
		fh = fopen( "C:\\trades_buy_"+Name()+".csv", "awr"); 
		if( fh) 
		{ 
			fputs(Name()+","+Date()+","+BuyPrice+","+BuyTP+","+BuySL+","+ round(BuySL*0.9995*10)/10+","+lotSizeb, fh);
			StaticVarSet("EntrySignal"+Name() , 0); 			 
			fclose( fh );
		}
	} 

	

    
	if ((StaticVarGet("EntrySignal"+Name()) == 1) && LastValue( Sell)) {
      fh = fopen( "C:\\trades_sell_"+Name()+".csv", "awr"); 
      if( fh) 
		{
			fputs(Name()+","+Date()+","+SellPrice+","+SellTP+","+ SellSL+","+round(SellSL*1.0005*10)/10+","+lotSizes , fh);
			StaticVarSet("EntrySignal"+Name() , 0);
			fclose( fh );
		}
	}
 
  
  


Filter=Buy OR Sell;