help in ichimoku please...

please i need your help to add the weekly kumo and weekly teneken and kugen lines in the daily chart of ichimoku...
this is my afl of ichimoku;

// Ichimoku Kinko Hyo Chart
// Abo Elias May-20-2008

//////////////////////////////
// 1) Tenkan-Sen = Conversion Line = (Highest High + Lowest Low) / 2, for the past 9 periods
// 2) Kijun-Sen = Base Line = (Highest High + Lowest Low) / 2, for the past 26 periods
// 3) Chikou Span = Lagging Span = Today's closing price plotted 26 periods behind
// 4) Senkou Span A = Leading Span A = (Tenkan-Sen + Kijun-Sen) / 2, plotted 26 periods ahead
// 5) Senkou Span B = Leading Span B = (Highest High + Lowest Low) / 2, for the past 52 periods, plotted 26 periods ahead
// Kumo = Cloud = Area between Senkou Span A AND B
// http://www.prosticks.com/education/ikh.php
//////////////////////////////


_SECTION_BEGIN("Price");
HAswitch = ParamToggle("Heikin Ashi","Off,On");
PriceUpCol = ParamColor("Price UP Color",colorGreen);
PriceDnCol = ParamColor("Price DN Color",colorRed);
PriceSty = ParamStyle("Price Style",styleCandle,maskDefault | styleCandle | styleBar);

HaClose = ( O+H+L+C ) / 4;
HaOpen = AMA( Ref(HaClose, -1), 0.5);
HaHigh = Max(H, Max(HaClose, HaOpen));
HaLow = Min(L, Min(HaClose, HaOpen));

if(HAswitch)
PlotOHLC(HaOpen,HaHigh,HaLow,HaClose,"Heikin Ashi",IIf(HaClose > HaOpen,PriceUpCol,PriceDnCol),PriceSty);
else
Plot(C,"Price",IIf(C > Ref(C,-1), PriceUpCol, PriceDnCol), PriceSty);
_SECTION_END();

_SECTION_BEGIN("Tenkan-Sen");
TenkanPer = Param("Tenkan-Sen Period",9,1,100,1);
TenkanCol = ParamColor("Tenkan-Sen Color",colorRed);
TenkanSty = ParamStyle("Tenkan-Sen Style",styleLine | styleThick);
Tenkan = ( HHV(H,TenkanPer) + LLV(L,TenkanPer) ) / 2;
Plot(Tenkan,"Tenkan",TenkanCol,TenkanSty);
_SECTION_END();

_SECTION_BEGIN("Kijun-Sen");
KijunPer = Param("Kijun-Sen Period",26,1,100,1);
KijunCol = ParamColor("Kijun-Sen Color",colorBlue);
KijunSty = ParamStyle("Kijun-Sen Style",styleLine | styleThick);
Kijun = ( HHV(H,KijunPer) + LLV(L,KijunPer) ) / 2;
Plot(Kijun,"Kijun",KijunCol,KijunSty);
_SECTION_END();

_SECTION_BEGIN("Chikou Span");
ChikouShft = Param("Chikou Span Shift",26,1,100,1);
ChikouCol = ParamColor("Chikou Span Color",colorViolet);
ChikouSty = ParamStyle("Chikou Span Style",styleLine | styleNoLabel);
Chikou = C;
Plot(Chikou,"",ChikouCol,ChikouSty,Null,Null,-ChikouShft);
_SECTION_END();

_SECTION_BEGIN("Senkou-Kumo");
SenkouKumoShft = Param("Senkou-Kumo Shift",26,0,100,1);
_SECTION_END();

_SECTION_BEGIN("Senkou Span A");
SenkouACol = ParamColor("Senkou Span A Color",colorSeaGreen);
SenkouASty = ParamStyle("Senkou Span A Style",styleLine);
SenkouA = ( Tenkan + Kijun ) / 2;
Plot(SenkouA,"Senkou A",SenkouACol,SenkouASty,Null,Null,SenkouKumoShft);
_SECTION_END();

_SECTION_BEGIN("Senkou Span B");
SenkouBPer = Param("Senkou Span B Period",52,1,200,1);
SenkouBCol = ParamColor("Senkou Span B Color",colorPink);
SenkouBSty = ParamStyle("Senkou Span B Style",styleLine);
SenkouB = ( HHV(H,SenkouBPer) + LLV(L,SenkouBPer) ) / 2;
Plot(SenkouB,"Senkou B",SenkouBCol,SenkouBSty,Null,Null,SenkouKumoShft);
_SECTION_END();

_SECTION_BEGIN("Kumo");
KumoUpCol = ParamColor("Kumo UP Color",colorSeaGreen);
KumoDnCol = ParamColor("Kumo DN Color",colorPink);
PlotOHLC(SenkouA,SenkouA,SenkouB,SenkouB,"",IIf(SenkouA>SenkouB,KumoUpCol,KumoDnCol),styleCloud | styleNoLabel,Null,Null,SenkouKumoShft);
_SECTION_END();



/*
Interpreting the Chart

Strong signals - A strong Buy Signal occurs when the Tenkan-Sen crosses above the Kijun-Sen from below.
A strong Sell Signal occurs when the opposite occurs. The signals must be above the Kumo.

Normal signals - A normal Buy Signal occurs when the Tenkan-Sen crosses above the Kijun-Sen from below.
A normal Sell Signal occurs when the opposite occurs. The signals must be within the Kumo.

Weak signals - A weak Buy Signal occurs when the Tenkan-Sen crosses above the Kijun-Sen from below.
A weak Sell Signal occurs when the opposite occurs. The signals must be below the Kumo.

Overall strength - Strength is shown to be with the sellers if the Chikou Span is below the current price.
Strength is shown to be with the buyers when the opposite is True.

Support/resistance levels - Support AND resistance levels are represented by the presence of the Kumo.
if the price is entering the Kumo from below, then the price is at a resistance level.
if the price is falling into the Kumo, then there is a support level.

Trends - Trends can be determined by simply looking at where the current price is in relation to the Kumo.
if the price stays below the Kumo, then there is a downward trend (bearish).
Alternatively, if the price stays above the Kumo, then there is an upward trend (bullish).